Comment réinitialiser les icônes de notification dans la barre d’état système de la barre des tâches - Windows 11
Au fur et à mesure que vous installez des applications la zone de notification de Windows 11 enregistre les icônes de ces applications que vous pouvez ou non rendre visibles dans la barre des tâches de l'écran d'accueil via l'option Paramètres de la barre des tâches en faisant 1 droit sur celle-ci puis dans la page qui s'ouvre cliquer sur la ligne Sélectionner les icônes à afficher dans la barre des tâches et libre à vous de sélectionner celles que vous souhaitez voir apparaître.
En générale cela se résume à 7 ou 8 icônes dont celles système mais toutes les autres sont enregistrées dans les paramètres de la barre des tâches et comme écrit plus haut "s'empilent"
En générale cela se résume à 7 ou 8 icônes dont celles système mais toutes les autres sont enregistrées dans les paramètres de la barre des tâches et comme écrit plus haut "s'empilent"
Procédure
Ouvrir le bloc notes
Copier/Coller l'intégralité du code ci-dessous
Fermer le bloc notes ► Enregistrer sous ► Réinitialiser les icônes de notification dans la barre d’état système de la barre des tâches.bat
Pour info ce fichier est également disponible en téléchargement direct au bas de cette page
Code : Tout sélectionner
@echo off
set regPath=HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify
set regKey1=IconStreams
set regKey2=PastIconsStream
echo.
echo The explorer process must be temporarily killed before deleting your taskbar corner overflow notification icons cache.
echo.
echo Please SAVE ALL OPEN WORK before continuing.
echo.
pause
REG DELETE "HKCU\Control Panel\NotifyIconSettings" /F
echo.
taskkill /IM explorer.exe /F
echo.
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey1% ^| find /i "%regkey1%"') do goto IconStreams
echo Registry key "IconStreams" already deleted.
echo.
:verify-PastIconsStream
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey2% ^| find /i "%regkey2%"') do goto PastIconsStream
echo Registry key "PastIconsStream" already deleted.
echo.
goto restart
:IconStreams
reg delete "%regpath%" /f /v "%regkey1%"
goto verify-PastIconsStream
:PastIconsStream
reg delete "%regpath%" /f /v "%regkey2%"
:restart
echo.
echo.
echo You will need to restart the PC to finish resetting your taskbar corner overflow notification icons.
echo.
CHOICE /C:YN /M "Do you want to restart the PC now?"
IF ERRORLEVEL 2 goto no
IF ERRORLEVEL 1 goto yes
:no
echo.
echo.
echo Restarting explorer....
echo.
echo Please remember to restart the PC later to finish resetting your taskbar corner overflow notification icons.
echo.
start explorer.exe
pause
exit /B
:yes
shutdown /r /f /t 00
Exécuter le fichier Réinitialiser les icônes de notification dans la barre d’état système de la barre des tâches.bat
Suivre les instructions de l'invite de commande pour réinitialiser les icônes de notification du coin de la barre des tâches.
Redémarrer le PC
Une fois terminé, vous pouvez supprimer le fichier Réinitialiser les icônes de notification dans la barre d’état système de la barre des tâches.bat téléchargé si vous le souhaitez ou bien le conserver pour une prochaine utilisation.
Toutes les icônes superflues qui étaient stockées dans les paramètres de la barre des tâches ont été supprimées et il ne vous reste plus qu'à réinitialiser les icônes souhaitées voir dans votre barre des tâches en faisant 1 droit sur la barre des tâches ► Paramètres de la barre des tâches ► Dans la fenêtre qui s'ouvre ► Faire 1 clic sur la ligne Autres icones de barre d'état système ► Mettre sur Activé les icônes que vous souhaitez voir dans la barre des tâches
Après la réinitialisation
Activer vos icônes favorites