[TUTO] Couper/Restaurer la connexion internet d'un double-clic

[Coccinelle]

Couper/Restaurer la connexion Internet d'un double-clic

Bien que l'utilisation d'un pare-feu permette de contrôler les connexions en entrée/sortie des applications, pouvoir couper temporairement la connexion Internet peut aussi avoir son utilité. C'est ce qu'on va voir ici.

Jusqu'à maintenant j'utilisais le petit utilitaire InternetOFF, toujours aussi efficace malgré son ancienneté. Mais aussi petite soit-elle, cette application doit être lancée au démarrage de Windows. Ça fait donc encore un truc au démarrage, donc ça prend du temps, ça prend de la RAM etc... Voici donc la parade avec un simple script batch qui fonctionne comme une bascule.

Le script

Copier le code ci-dessous dans un simple fichier texte que vous aurez renommé en lui donnant l'extension  .cmd  :

Code : Tout sélectionner

@ECHO OFF
CHCP 1252 >NUL
TITLE INTERNET ON/OFF
color 9f

:: ===============================================================================
:: DEBUT OBTENIR LES DROITS ADMINISTRATEURS SUR LE FICHIER BATCH
set "params=%*"
cd /d "%~dp0" && ( if exist "%temp%\getadmin.vbs" del "%temp%\getadmin.vbs" ) && fsutil dirty query %systemdrive% 1>nul 2>nul || (  echo Set UAC = CreateObject^("Shell.Application"^) : UAC.ShellExecute "cmd.exe", "/k cd ""%~sdp0"" && %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs" && "%temp%\getadmin.vbs" && exit /B )
:: FIN DROITS ADMINISTRATEURS SUR LE FICHIER BATCH
:: ===============================================================================

if not exist "%CD%\disable" goto :disable else goto :enable

:enable
netsh interface set interface name="Ethernet 2" admin=enabled
del "%CD%\disable" /q
color 2f
echo INTERNET ACTIVÉ !
timeout 5
exit

:disable
netsh interface set interface name="Ethernet 2" admin=Disabled
color cf
echo "INTERNET DÉSACTIVÉ" > "%CD%\disable"
echo INTERNET DÉSACTIVÉ !
timeout 5
exit

L'utilisation

pour désactiver la connexion
pour la réactiver

Pré-requis

Pour que ce script fonctionne, il faut connaître le nom de l'interface à déconnecter, nom qu'il faudra intégrer dans le script à la place du nom de mon interface à moi, ici Ethernet 2 !

Ensuite, il faudra passer par les propriétés de l'interface réseau choisie ( sur le réseau puis Configurer/Gestion de l'alimentation), afin de désactiver la sortie de veille. Sinon à chaque fois que vous désactiverez la connexion, elle se rétablira dans les secondes qui suivent.

Enfin, placez ce script dans un petit dossier à vous, puis tirez un lien pointant vers le script. Et voilà ! Chaque coupera ou restaurera votre connexion Internet.

Merci la Coccinelle.